src/dlsint.mac

   1 TITLE   DLSINT - INT. SERV. FOR DLS (DATA LINE SCANNER DC10)\r
   2 SUBTTL  M.FREDRIKSEN/RCC TS  01 JUN 69 V005\r
   3 XP      VDLSIT,005\r
   4                 ;PUT VERSION NUMBER IN GLOB LISTING AND LOADER STORAGE MAP\r
   5 \r
   6 ;MODULAR HARDWARE INTERFACE WITH EITHER SCNSER OR TTYSER\r
   7 \r
   8 EXTERN TYPX\r
   9 \r
  10 IFE FTTTYSER,<XP FULTWX,200000>\r
  11 \r
  12 IFN FTTTYSER,<XP FULTWX,4>\r
  13 \r
  14 ;ACCUMULATOR ASSIGNMENTS\r
  15 \r
  16         CHREC=TEM       ;AC FOR CHARACTER\r
  17         DDB=DEVDAT      ;ADDRESS OF DEVICE DATA BLOCK\r
  18         LINE=TAC1       ;SCANNER LINE NUMBER\r
  19         HPOS=DAT        ;HORIZONTAL POSITION OF TTY.(0-71)\r
  20 \r
  21 ;BYTE POINTERS\r
  22 \r
  23 \r
  24 EXTERNAL PLASTC\r
  25 \r
  26 \r
  27 \r
  28 \r
  29 DLS=240                 ;DC10 DEVICE NUMBER\r
  30 ;BITS IN CHREC TO COMMUNCATE WITH DLS\r
  31 \r
  32 USDRLN=100              ;USE DIRECTED LINE NUMBER\r
  33 TDSABL=400              ;TRANSMIT DISABLE\r
  34 RCVBIT=400              ;RECEIVE BIT AFER DATAI DLS,CHREC\r
  35 \f\r
  36 ;DEVICE DEPENDENT PORTION OF INITIALIZATION CODE\r
  37 ;CALL:  MOVEI   TAC,CHANNEL NUMER\r
  38 ;       PUSHJ   PDP,SCNINI\r
  39 \r
  40 INTERNAL SCNINI\r
  41 DLSINI:\r
  42 SCNINI: CONO    DLS,40          ;INIT DLS COMPLETELY (I/O/RESET)\r
  43         CONO    DLS,(TAC)       ;ASSIGN PI CHANNEL NUMBER\r
  44         POPJ    PDP,\r
  45 \r
  46 ;SCANNER INTERRUPT SERVICE ROUTINE\r
  47 \r
  48 ENTRY DLSINT\r
  49 \r
  50 INTERNAL SCNINT\r
  51 EXTERNAL SCNSAV,TCONLN,TTYTAB,XMTINT,TYPE,INUS2,RECINT\r
  52 \r
  53 DLSINT:\r
  54 SCNINT: CONSO   DLS,30          ;ANY INTERRUPTS ON DLS\r
  55         JRST SCNINT             ;NO\r
  56         JSR SCNSAV\r
  57         DATAI   DLS,CHREC       ;GET CHARACTER & LINE INFO\r
  58         HLRZ    LINE,CHREC      ;PUT LINE NUMBER IN AC LINE\r
  59         CAIL    LINE,TCONLN     ;ARE WE ENABLED FOR THIS LINE NUMBER?\r
  60         JRST    SCNIN2          ;NO,TURN OFF TRANSMIT(IF ON) AND DISMISS\r
  61         TRNE    CHREC,RCVBIT    ;WAS IT A RECEIVER INTERRUPT?\r
  62         JRST    RECINT          ;YES, RECEIVER INT. HANDLER\r
  63         DATAO   DLS,[EXP TDSABL]        ;CLEAR HARDWARE FLAG\r
  64         JRST    XMTINT          ;GO PROCESS CHAR IN SCNSRF OR SCNSRH\r
  65 \f;COMMON PARTS OF CTY AND SCANNER INTERRUPT SERVICE ROUTINES.\r
  66 \r
  67 EXTERNAL INJEST,DDBSRC\r
  68 INTERNAL TCOMM\r
  69 \r
  70 TCOMM:\r
  71         SKIPE DDB,TTYTAB(LINE)  ;DATA BLOCK ASSIGNED?\r
  72         JRST INUSE              ;YES\r
  73         PUSHJ PDP,DDBSRC        ;SEARCH FOR FREE TTY DEV. DATA BLOCK\r
  74         JRST TYPX               ;NONE FOUND, TYPE X\r
  75         MOVEI HPOS,0            ;ASSUME TTY IS AT BEGIN OF FORM\r
  76         CAILE LINE,TCONLN       ;PSEUDO CONSOLE?\r
  77         JRST INJEST             ;YES\r
  78         CAIN    LINE,TCONLN     ;IS IT THE CTY ?\r
  79         JRST INUS2              ;YES, ACCPT CHAR AND PROCESS\r
  80         JRST TYPE               ;NO, ECHO CHAR ON FULL DUPLEX\r
  81                                 ;BEFORE PROCESSING IT\r
  82 \r
  83                                 ;HERE IF LINE NUMBER TOO BIG\r
  84 SCNIN2: DATAO   DLS,[EXP TDSABL]                ;SET TRANSMIT DISABLE BIT AND OUTPUT IT\r
  85                                 ;(JUST INCASE, ELSE IT WILL INTERRUPT IMMEDIATLY AGAIN)\r
  86         POPJ    PDP,            ;DISMISS INTERRUPT\r
  87 \f;COMMON TO RECEIVE AND TRANSMIT.\r
  88 \r
  89 INUSE: HRRZS  DDB       ;LINE DISABLED IF RH TTYTAB=-1\r
  90         CAIN DDB,-1\r
  91         POPJ PDP,\r
  92         MOVE IOS,DEVIOS(DDB)    ;SETUP IOS\r
  93         CAIL    LINE,TCONLN     ;CTY OR PTY ?\r
  94         JRST INUS2              ;YES\r
  95         TLNE IOS,FULTWX         ;IS THIS SELF ECHOEING FULL DUPLEX?\r
  96         JRST INUS2              ;YES,(USER TYPED CONROL B)\r
  97         HRL     CHREC,LINE      ;INSERT LINE NUMBER IN DATAO\r
  98         TLO     CHREC,USDRLN\r
  99         TRZ     CHREC,TDSABL\r
 100         DATAO   DLS,CHREC\r
 101         DPB CHREC,PLASTC\r
 102         POPJ PDP,               ;DISMISS INTERRUPT\r
 103 \r
 104 ;ROUTINE TO OUTPUT A CHARACTER ON A LINE\r
 105 ;CALLED FROM TYP OR TYPL IN SCNSER\r
 106 \r
 107 INTERNAL SCNTYP\r
 108 \r
 109 SCNTYP:\r
 110 DLSTYP: HRL     CHREC,LINE      ;SET UP LINE NUMBER IN CHREC\r
 111         TLO     CHREC,USDRLN            ;USE THAT AS DIRECTED LINE#\r
 112         TRZ     CHREC,TDSABL            ;INSURE TRANSMISSION NOT DISABLED\r
 113         DATAO   DLS,CHREC               ;OUT IT GOES\r
 114         SKIPE   DDB\r
 115         DPB CHREC,PLASTC        ;SAVE CHAR FOR FULL DUPLEX\r
 116         POPJ PDP,\r
 117 \r
 118         LIT\r
 119 DLSEND: END\r