src/ptysrh.mac

   1 TITLE   PTYSRH - HALF DUPLEX PSEUDO TELETYPE SERVICE ROUTINES\r
   2 SUBTTL  D. WITCRAFT/RAP  TS3.19  24 SEP 68  V004\r
   3 XP      VPTYSF,004\r
   4                 ;PUT VERSION NUMBER IN GLOB LISTINGS AND LOADER STORAGE MAP\r
   5 \r
   6 ENTRY PTYSRH            ;DUMMY GLOBAL FOR FULL DUPLEX PTY\r
   7 PTYSRH:\r
   8 \r
   9 \r
  10 \r
  11 ;ACCUMULATOR ASSIGNMENTS\r
  12 \r
  13         DDB=DEVDAT\r
  14         LINE=TAC1\r
  15 \r
  16         CHREC=TEM\r
  17         SCNHAC=12\r
  18         PIOS=13\r
  19         PDDB=14\r
  20         RPTB=400\r
  21 \r
  22         SP=2000                 ;SPECIAL TTY CHARACTER\r
  23         T37=10000               ;MODEL 37-FULL CHARACTER SET\r
  24 SYNC=40000              ;BREAK CHARACTER SEEN---FROM SCNSER\r
  25 \r
  26 ;PTY DEVICE DEPENDENT IO STATUS BITS (RH DEVIOS)\r
  27 \r
  28 IOPTW=4000              ;OUTPUT WAIT (OBJ. JOB HAS DONE INPUT)\r
  29 IOPTRE=2000             ;PTY RESPONSE IS READY\r
  30 MONMOD=1000             ;PTY IS IN MONITOR MODE\r
  31 \r
  32 INTERNAL FTCHECK,FTMONP\r
  33 IFN FTCHECK+FTMONP,<\r
  34 EXTERNAL PTYDDB,PTYCSV,PTYSAC,PTYBND,PTYBM1,PTYDDS,PIOSAV,PDDSAV\r
  35 EXTERNAL PTYSAV,PTYSA2,PTYRET,PACSAV\r
  36 INTERNAL PTYSA0,PTYRE0,ACSAV0\r
  37 >\r
  38 IFE FTCHECK+FTMONP,<\r
  39 ;PSEUDO CONSOLE DEVICE DATA BLOCK\r
  40 ;REMAINING PTY DDB'S ARE GENERATED\r
  41 ;OUT OF LINE AT BUILD TIME\r
  42         INTERN  PTYDDB\r
  43         ZZ=.\r
  44 PTYDDB: SIXBIT  /PTY0/\r
  45         XWD     0,10000+STTYBF+1        ;PTY0 IS UNIT 1,PTY1 IS UNIT 2, ETC.\r
  46         Z\r
  47         EXP     PTYDSP\r
  48         XWD     DVIN+DVOUT,3\r
  49         Z\r
  50         XWD     PROG,0\r
  51         XWD     PROG,0\r
  52         Z\r
  53         XP      PTYCSV,.-ZZ\r
  54         Z\r
  55         XP      PTYSAC,.-ZZ\r
  56         BLOCK   13\r
  57         XP      PTYBND,PTYSAC+12\r
  58         XP      PTYBM1,PTYBND-1\r
  59         XP      PTYDDS,.-ZZ     ;SIZE OF PTY DDB\r
  60 \r
  61 PTYSA2: BLT     SCNHAC,0\r
  62 PIOSAV: 0\r
  63 PDDSAV: 0\r
  64 >\r
  65 \fINTERNAL PTYDSP\r
  66 EXTERNAL OUT\r
  67         POPJ    PDP,    ;INITIALIZE\r
  68         POPJ    PDP,            ;PRINT ERROR, STOP JOB\r
  69 PTYDSP: JRST PTYREL\r
  70         JRST OUT\r
  71         JRST PTYOUT\r
  72         JRST PTYIN\r
  73 \fEXTERNAL PTYTAB,TCONLN,TTYTAB,TTYKIL\r
  74 \r
  75 PTYREL: LDB LINE,[POINT 6,DEVCHR(DDB),23]\r
  76         SETZM PTYTAB(LINE)\r
  77         ADDI LINE,TCONLN\r
  78         SKIPN TTYTAB(LINE)\r
  79         POPJ PDP,\r
  80         PUSH PDP,DDB\r
  81         HRRZ DDB,TTYTAB(LINE)\r
  82         PUSHJ PDP,TTYKIL\r
  83         POP PDP,DDB\r
  84         POPJ PDP,\r
  85 \f;PTY OUTPUT\r
  86 ;IF NO TTYTAB ENTRY EXISTS FOR THIS PTY, A SPACE IS\r
  87 ;SENT TO SCNSER (TCOMM) CAUSING AN ENTRY TO BE MADE IF\r
  88 ;A TTY DATA BLOCK IS AVAILABLE.  IF NONE IS AVAILABLE,\r
  89 ;AN "X" IS RETURNED IN WHICH CASE IODERR IS SET IN PTY STATUS\r
  90 ;AND OUTPUT IS TERMINATED.\r
  91 \r
  92 ;IF A TTY DEVICE DATA BLOCK IS AVAILABLE, CHARACTERS ARE\r
  93 ;TRANSMITTED TO TCOMM. IF A RESPONSE IS RECIEVED AS INDICATED\r
  94 ;BY THE SP BIT IN TTY STATUS, THE PTY OUTPUT BUFFER IS\r
  95 ;ADVANCED IOPTRE IS SET IN PTY STATUS , AND CONTROL RETURNS\r
  96 ;TO THE OUPTUT UUO AND THENCE TO THE USER.\r
  97 ;IF NO RESPONSE IN ENCOUNTERED, OUTPUT PROCEEDS IN THE \r
  98 ;NORMAL FASHION ADVANCING THE PTY OUTPUT BUFFERS\r
  99 ;UNTIL THEY ARE EMPTY.\r
 100 \r
 101 ;IOPTRF IS SET EVERY TIME THE JOB RUNNING 0N THE PTY (OBJECT JOB)\r
 102 ;DOES AN "OUTPUT" UUO.  IOPTW IS SET WHENEVER THE OBJECT JOB DOES\r
 103 ;AN INPUT, THE OBJECT JOB THEN GOES INTO I/O WAIT UNTIL THE JOB WITH\r
 104 ;THE PTY ASSIGNED (CONTROL JOB) HAS COMPLETED ITS OUTPUT UUO.\r
 105 ;MONMUD INDICATES PTY IS IN MONITOR MODE (ITS LINKED TTYDDB HAS TPMON\r
 106 ;SET IN THE OF IOS)\r
 107 \r
 108 \r
 109 EXTERNAL TCOMLN,TTYTAB,TCOMM,TPYTAB,PTYTAB,ITMCNT,SETIOD\r
 110 EXTERNAL ADVBFE,PUNIT\r
 111 \r
 112 PTYOUT: LDB LINE,PUNIT\r
 113         JSR PTYSAV\r
 114         SKIPN PTYTAB(LINE)\r
 115         HRRZM DDB,PTYTAB(LINE)\r
 116         SKIPE TPYTAB(LINE)      ;HAS A TTY DDB BEEN ASSIGNED?\r
 117         JRST PTYOU0-1           ;YES\r
 118         ADDI LINE,TCONLN\r
 119         MOVEI CHREC,240         ;NO\r
 120         PUSHJ PDP,TCOMM\r
 121         CAIE CHREC,"X"          ;ANY AVAILABLE?\r
 122         JRST PTYOU6             ;YES\r
 123         JSR PTYRET\r
 124         TRO IOS,DEVIOS(DDB)     ;NO\r
 125         MOVEM IOS,DEVIOS(DDB)\r
 126         POPJ PDP,\r
 127 \r
 128 PTYOU6: TLO     IOS,T37+IOFST   ;FORCE BUFFER RESET\r
 129                                 ;T37 SO TABS, ETC NOT TRNSLATED (TIMING ERRO OTHERWI)\r
 130         MOVEM IOS,DEVIOS(DDB)\r
 131         JSR PTYRET              ;RESTORE ACS\r
 132 \r
 133 PTYOU0: TRNE    IOS,IOPTRE\r
 134         POPJ    PDP,\r
 135         TLZE IOS,IOBEG          ;FIRST IO\r
 136         TLO IOS,IOFST           ;YES\r
 137         TLZN IOS,IOFST          ;FIRST ITEM IN BUFFER?\r
 138         JRST PTYOU1             ;NO\r
 139         TLO IOS,IO              ;YES. INITIALIZE POINTER & COUNT\r
 140         HRRZ TAC,DEVOAD(DDB)\r
 141         ADD TAC,[XWD 700,1]\r
 142         ADDI TAC,(PROG)\r
 143         MOVEM TAC,DEVOAD(DDB)\r
 144         HRRZ ITEM,@TAC\r
 145         JUMPE ITEM,PTYOU8       ;BUFFER EMPTY>\r
 146 \f       PUSHJ PDP,ITMCNT\r
 147         MOVEM ITEM,DEVCTR(DDB)\r
 148 \fPTYOU1:        TRO IOS,IOACT\r
 149         TRZ IOS,IOPTRE\r
 150         JSR PTYSAV              ;SAVE ACS\r
 151         LDB     LINE,PUNIT\r
 152         ADDI LINE,TCONLN\r
 153         EXCH    IOS,PIOS\r
 154 \r
 155 PTYOU2: SOSGE DEVCTR(PDDB)      ;BUFFER EMTY?\r
 156         JRST PTYOU3             ;YES\r
 157         ILDB CHREC,DEVOAD(PDDB) ;NO\r
 158 PTYOU7: PUSHJ PDP,TCOMM         ;SEND NEXT CHARACTER\r
 159         TLNE IOS,IOFST\r
 160         JRST PTYOU3\r
 161         TLNE    IOS,SP          ;SPECIAL CHARACTER ECHO?\r
 162         JRST    PTYOU4          ;YES, SEE IF CONTROL CHAR ECHO\r
 163         TLNE    IOS,SYNC        ;NO. BREAK CHARACTER SEEN IF OBJ. JOB SWAPPED OUT?\r
 164         JRST    PTYOU3          ;YES, BUFFER NOT MOVED INTO OBJECT\r
 165                                 ;JOB TTY IN BUFFER \r
 166         JRST PTYOU2             ;NO\r
 167 \r
 168 PTYOU4: CAIE CHREC,"^"\r
 169         JRST PTYOU7\r
 170         MOVEM CHREC,PTYCSV(PDDB);YES. FLUSH OUTPUT\r
 171         MOVEM IOS,DEVIOS(DDB)   ;SAVE TTY STATE\r
 172         TRO PIOS,IOPTRE         ;LET USER KNOW\r
 173 \r
 174 PTYOU3: JSR PTYRET              ;RESTORE ACS\r
 175         EXCH    IOS,PIOS\r
 176 PTYOU8: TLZE IOS,IOW\r
 177         PUSHJ PDP,SETIOD        ;START PTY JOB\r
 178         HRLI    TAC,PROG\r
 179         HRL     TAC,DEVBUF(DDB)\r
 180         HRR     TAC,@TAC\r
 181         MOVEM   TAC,DEVOAD(DDB)\r
 182         PUSHJ PDP,ADVBFE        ;ADVANCE PTY OUTPUT BUFFER\r
 183         JRST PTYOU5             ;NEXT BUFFER IS EMPTY.\r
 184         TRNN PIOS,IOPTRE        ;RESPONSE?\r
 185         JRST PTYOU0             ;NO\r
 186         TRO IOS,IOPTRE          ;YES, SET RESPONSE FLAG AND RETURN TO USER\r
 187 PTYOU5: TRZ IOS,IOACT+IOPTW     ;CONSIDER OUTPUT COMPLETED\r
 188         TLO IOS,IOFST\r
 189         MOVEM IOS,DEVIOS(DDB)\r
 190         POPJ PDP,\r
 191 \fEXTERNAL TCONLN,TTYTAB,SETIOD,STODAT,ADVBFF,STOSQD,ADRERR\r
 192 \r
 193 PTYIN:  LDB LINE,[POINT 6,DEVCHR(DDB),23]\r
 194         ADDI LINE,TCONLN\r
 195         HRRZ PDDB,TTYTAB(LINE)  ;TTY DDB ADDRESS\r
 196         JUMPN PDDB,PTYIN1       ;HAS TTY DDB BEEN LOST?\r
 197         TRO IOS,IOIMPM          ;YES, THAT'S ALL.\r
 198         JRST PTYIN8\r
 199 \r
 200 PTYIN1: PUSH PDP,LINE\r
 201         TLO IOS,IOFST\r
 202         TDZ IOS,[XWD IO,IOPTRE]\r
 203         MOVEI   TAC,440700+PROG\r
 204         HLLM    TAC,DEVPTR(DDB)\r
 205 \r
 206         TRO IOS,IOACT\r
 207         MOVE PIOS,DEVIOS(PDDB)\r
 208         TLNN PIOS,IO+SP\r
 209         JRST PTYI10\r
 210         SETZM CHREC\r
 211         EXCH CHREC,PTYCSV(DDB)  ;HAS FIRST CHAR BEEN REC?\r
 212         JUMPE CHREC,PTYIN5+1    ;NO\r
 213                                 ;YES,SAVE LINE NO.\r
 214 PTYIN4: TLNN PIOS,IO+SP         ;IS TTY DONE?\r
 215         JRST PTYI3B             ;YES. THATS ALL\r
 216         MOVE DAT,CHREC\r
 217         PUSHJ PDP,STODAT        ;STORE CHARACTER\r
 218         JRST    ADRERR\r
 219         JRST PTYIN6             ;BUFFER FULL\r
 220 \r
 221 PTYIN5: JUMPE ITEM,PTYI3A       ;IF COUNT RUNS OUT\r
 222         EXCH PIOS,IOS           ;NO. GET NEXT CHAR.\r
 223         EXCH PDDB,DDB           ;SET IOS AND DBD FOR TTY\r
 224         POP PDP,LINE            ;RESTORE LINE NO.\r
 225         PUSH PDP,ITEM           ;SAVE ITEM COUNT\r
 226         PUSH PDP,PROG\r
 227         PUSHJ PDP,TCOMM\r
 228         POP PDP,PROG\r
 229         POP PDP,ITEM            ;RESTORE ITEM COUNT\r
 230         EXCH PIOS,IOS\r
 231         EXCH PDDB,DDB\r
 232         PUSH PDP,LINE\r
 233         JRST PTYIN4\r
 234 \fPTYI3A:        TRZ     IOS,IOBKTL\r
 235         TRO     IOS,IOPTRE      ;INPUT READY\r
 236 PTYI3B: PUSHJ PDP,STOSQD\r
 237         JRST    ADRERR\r
 238         TLOA IOS,IOFST\r
 239 \r
 240 PTYIN6: TRO     IOS,IOPTRE+RPTB\r
 241         PUSHJ PDP,ADVBFF        ;ADVANCE PTY BUFFER\r
 242         JRST PTYI10             ;NEXT BUFFER IS FULL.\r
 243         TLO IOS,IOFST\r
 244         TRZE IOS,RPTB\r
 245         JRST PTYIN5+1\r
 246 PTYI10: TLZE IOS, IOW\r
 247         PUSHJ PDP, SETIOD\r
 248         TRZ IOS,IOACT+RPTB\r
 249         POP PDP, LINE\r
 250 PTYIN8: MOVEM IOS, DEVIOS(DDB)\r
 251         POPJ PDP,\r
 252 \f;SAVE ACCUMULATORS\r
 253 ;CALL   MOVEI DDB,ADDRESS OF PTYDB\r
 254 ;       JSR PTYSAV\r
 255 \r
 256 \r
 257 IFE FTCHECK+FTMONP,<\r
 258 PTYSAV: 0\r
 259 >\r
 260 PTYSA0: MOVEM SCNHAC,PTYBND(DDB)        ;SAVE HIGH AC\r
 261         HRRZ SCNHAC,DDB\r
 262         ADDI SCNHAC,PTYBM1\r
 263         HRRM SCNHAC,PTYSA2\r
 264         SUBI SCNHAC,SCNHAC-1\r
 265         XCT     PTYSA2          ;DO BLT SCNHAC\r
 266         MOVE PDDB,DDB\r
 267         JRST @PTYSAV\r
 268 \r
 269 ;RESTORE ACCUMULATORS\r
 270 ;CALL   MOVEI PDDB,PTY DATA BLOCK ADDRESS\r
 271 ;       JSR PTYRET\r
 272 \r
 273 IFE FTCHECK+FTMONP,<\r
 274 PTYRET: 0\r
 275 >\r
 276 PTYRE0: HRRZ SCNHAC,PDDB\r
 277         ADDI SCNHAC,PTYSAC\r
 278         HRLZS   SCNHAC\r
 279         BLT SCNHAC,SCNHAC\r
 280         JRST @PTYRET\r
 281 \r
 282 ;SAVE ONLY PIOS AND PDDB\r
 283 \r
 284 IFE FTCHECK+FTMONP,<\r
 285 PACSAV: 0\r
 286 >\r
 287 ACSAV0: MOVEM   PIOS,PIOSAV\r
 288         MOVEM   PDDB,PDDSAV\r
 289         JRST    @PACSAV\r
 290 \r
 291 ACRET:  MOVE    PIOS,PIOSAV\r
 292         MOVE    PDDB,PDDSAV\r
 293         POPJ    PDP,\r
 294 \f;INTERCEPT TTY OUTPUT AT UUO LEVEL AND SYNCHRONIZE\r
 295 ;TTY OUTPUT WITH PTY INPUT\r
 296 \r
 297 \r
 298 INTERNAL PTYPE\r
 299 EXTERNAL TCONLN,PTYTAB,CLOCK,CIPWTM1,WAKE\r
 300 \r
 301 PTYPE:  MOVE PDDB,LINE\r
 302         SUBI PDDB,TCONLN\r
 303         HRRZ PDDB,PTYTAB(PDDB)\r
 304         TRO     IOS,IOACT       ;FORCE RESCHED TO CONTROL JOB\r
 305         MOVEM IOS,DEVIOS(DDB)\r
 306         MOVEI TAC,IOPTRE\r
 307         IORB TAC,DEVIOS(PDDB)\r
 308         MOVEM CHREC,PTYCSV(PDDB)        ;SAVE CHARACTER\r
 309 \r
 310 PTWAKE: PUSH PDP,TEM\r
 311         PUSH    PDP,TAC1\r
 312         LDB     TAC,[POINT 6,DEVCHR(PDDB),5]    ;PTY JOB NR\r
 313 \r
 314         HRRZ    TAC1,CLOCK              ;LAST JOB IN CLOCK QUEUE\r
 315 PTWAK2: CAIN    TAC1,CIPWTM1            ;LOOKED AT ALL JOBS\r
 316         JRST PTWAK1                     ;YES, WAS NOT SLEEPING\r
 317         HLRZ    TEM,(TAC1)              ;SLEEPING JOB?\r
 318         CAIE    TEM,WAKE\r
 319         SOJA    TAC1,PTWAK2             ;NO, IN QUEUE FOR SOME OTHER REASON\r
 320         LDB     TEM,[POINT 6,(TAC1),23] ;JOB NR IN QUEUE\r
 321         CAME    TEM,TAC                 ;IS IT THIS ONE?\r
 322         SOJA    TAC1,PTWAK2             ;LNO, LOOP TILL DONE\r
 323         MOVE    TEM,(TAC1)              ;YES, ZERO TIME LEFT TO SLEEP\r
 324         TRZ     TEM,7777\r
 325         AOS     TEM                     ;LADD ONE SO NEXT TICK WILL MAKE 0\r
 326         MOVEM   TEM,(TAC1)\r
 327 PTWAK1: POP     PDP,TAC1\r
 328         POP     PDP,TEM\r
 329         POPJ    PDP,\r
 330 \f;ROUTINES TO SET VARIOUS BITS\r
 331 ;CALLED FROM SCNSER WITH TTY LINE NUMBER IN LINE\r
 332 \r
 333 INTERNAL PTYOW,PTMNMD,PTMNMZ\r
 334 \r
 335 PTMNMD: PUSH    PDP,PIOS\r
 336         MOVEI   PIOS,MONMOD     ;PTY INTO MONITOR MODE\r
 337         JRST    PTYSET\r
 338 \r
 339 PTMNMZ: PUSH    PDP,PIOS\r
 340         HRROI   PIOS,MONMOD     ;PTY OUT OF MONITOR MODE\r
 341         JRST    PTYSET\r
 342 \r
 343 PTYOW:  PUSH    PDP,PIOS\r
 344         MOVEI   PIOS,IOPTW      ;PTY IN OUTPUT WAIT\r
 345 \r
 346 PTYSET: MOVE    PDDB,LINE\r
 347         SUBI    PDDB,TCONLN     ;FIND PTY THAT TTY IS LINKED TO\r
 348         HRRZ    PDDB,PTYTAB(PDDB)\r
 349         TLZE    PIOS,-1         ;BIT TO BE SET OR ZEEROED\r
 350         ANDCAB  PIOS,DEVIOS(PDDB)       ;ZEROED\r
 351         IORB    PIOS,DEVIOS(PDDB)\r
 352         TRNE    PIOS,IOPTW      ;IS LINKED TTY JOB IN INPUT WAIT?\r
 353         PUSHJ PDP,PTWAKE        ;YES, WAKE UP CONTROL JOB\r
 354         JRST ACRET\r
 355 \f       END\r
 356 \f\r
 357 \0\0\0\0